KiXforms Forum Index KiXforms
The Forum for the KiXforms Community
 
 FAQFAQ   SearchSearch   MemberlistMemberlist   UsergroupsUsergroups   RegisterRegister 
 ProfileProfile   Log in to check your private messagesLog in to check your private messages   Log inLog in 
 Quick Links 
Site News
Downloads
Documentation
Donations
Script Archive
Tracking Systems

ServAlert ping response

 
Post new topic   Reply to topic    KiXforms Forum Index -> Script Archive
View previous topic :: View next topic  
Author Message
bruno
KiXforms Regular
KiXforms Regular


Joined: 19 May 2003
Posts: 44
Location: France (Europe)

PostPosted: Thu Nov 25, 2004 3:55 pm    Post subject: ServAlert ping response Reply with quote

Here a script issue form Gargoyle last post.
Ping ping Very Happy
2 scripts:
ServAlert.kix
Code:

; ServAlert.kix
;
;Adapted by Bruno
;Issue form Gargoyle last post
;Many thanks to the forum users
;
Break On
SetConsole("hide")

SetTitle("Consol Alert")
 
;********* FORM CREATE BEGIN **********   

$System = CreateObject("Kixtart.System")
$Form = $System.Form()
 
$Form.icon=$System.BuiltinIcons(32)
$Form.BackColor = 212,208,200
$Form.ControlBox = "True"
$Form.DrawGrid = "True"
$Form.FontBold = "False"
$Form.FontItalic = "False"
$Form.FontName = "Microsoft Sans Serif"
$Form.FontSize = 8.25
$Form.FontUnderline = "False"
$Form.ForeColor = 0,0,0
$Form.FormBorderStyle = 4
$Form.Height = 300
$Form.Left = 0
$Form.MaximizeBox = "False"
$Form.MinimizeBox = "True"
$Form.SizeGripStyle = 0
$Form.StartPosition = 4
$Form.Tag = ""
$Form.Text = "ServAlert"
$Form.Top = 0
$Form.ToolTipText = ""
$Form.TopMost = "False"
$Form.Width = 464
$Form.WindowState = 0
$Form.NotifyIcon = $System.NotifyIcon()
$Form.NotifyIcon.Icon = $Form.icon
$Form.NotifyIcon.Text = $Form.Text
$Form.NotifyIcon.Visible = "False"
$Form.NotifyIcon.OnDoubleClick = "OnDoubleClick()"
 
;********* FORM CREATE END **********

$fraBanner = $Form.PictureBox
$fraBanner.BACKCOLOR = $Form.RGB(255,255,255)
$fraBanner.HEIGHT = 70
$fraBanner.Left= 15
$fraBanner.TOP   = 10
$fraBanner.WIDTH = $Form.Width-35

$fraBanner.FONTSIZE = 20
$fraBanner.FONTNAME = "verdana"
$fraBanner.ForeColor = 0
$fraBanner.PrintXY(10,0,"ServAlert")
$fraBanner.FONTSIZE = 8
$fraBanner.ForeColor = $Form.RGB(0,100,100)
$fraBanner.PrintXY(73,32,"Build with KiX v@KIX ")
$fraBanner.FONTBOLD = 0
$fraBanner.FONTSIZE = 8
$fraBanner.PrintXY(73,46,"and Kixforms v"+$Form.Version)
$fraBanner.FONTBOLD = 0
$fraBanner.FONTSIZE = 10

$lblGeneral = $Form.Label("Today "+@date,0,$Form.ClientHeight-17,$Form.ClientWidth-60,17)
$lblGeneral.BorderStyle = 5
$lblGeneral.Anchor = 2+4+8

$lblTime = $Form.Label(@time,$lblGeneral.Right+2,$Form.ClientHeight-17,57,17)
$lblTime.BorderStyle = 5
$lblTime.Anchor = 2+8

$tmrTime = $Form.Timer
$tmrTime.Interval = 1000
$tmrTime.OnTimer = "$$lblTime.Text = @@time"

;*************************************

$ListBoxx1 = $Form.Controls.ListBox()
$ListBoxx1.FontSize = 8,25
$ListBoxx1.Height = 95
$ListBoxx1.Left = 30
$ListBoxx1.ToolTipText = "Double click to add"
$ListBoxx1.Top = 105
$ListBoxx1.Width = 120
$listboxx1.sorted="true"
$listboxx1.ondoubleclick = "addpc()"

$ListBoxx2 = $Form.Controls.ListBox()
$ListBoxx2.FontSize = 8,25
$ListBoxx2.Height = 95
$ListBoxx2.Left = 180
$ListBoxx2.ToolTipText = "Double click to remove"
$ListBoxx2.Top = 105
$ListBoxx2.Width = 120
$listboxx2.sorted = "true"
$listboxx2.ondoubleclick = "rempc()"

$Buttonx1 = $Form.Controls.Button()
$Buttonx1.FontSize = 8,25
$Buttonx1.Height = 23
$Buttonx1.Left = 330
$Buttonx1.Text = "Save list"
$Buttonx1.Top = 75+60
$Buttonx1.Width = 75
$Buttonx1.onclick = "enr()"

$Labelx1 = $Form.Controls.Label()
$Labelx1.BackColor = 212,208,200
$Labelx1.FontSize = 8,25
$Labelx1.Height = 14
$Labelx1.Left = 30
$Labelx1.Text = "Aviable:"
$Labelx1.Top = 90
$Labelx1.Width = 120

$Labelx2 = $Form.Controls.Label()
$Labelx2.BackColor = 212,208,200
$Labelx2.FontSize = 8,25
$Labelx2.Height = 14
$Labelx2.Left = 180
$Labelx2.Text = "List to check:"
$Labelx2.Top = 90
$Labelx2.Width = 119
   
$Button1 = $Form.Controls.Button
$Button1.Anchor = 5
$Button1.TextAlign = 32
$Button1.Enabled = "False"
$Button1.FlatStyle = 2
$Button1.FontBold = "False"
$Button1.FontItalic = "False"
$Button1.FontName = "Microsoft Sans Serif"
$Button1.FontSize = 8.25
$Button1.FontUnderline = "False"
$Button1.ForeColor = 0,0,0
$Button1.Height = 23
$Button1.Left = 45
$Button1.TabStop = "True"
$Button1.Tag = ""
$Button1.Text = "Run"
$Button1.ToolTipText = ""
$Button1.Top = 210
$Button1.Visible = "True"
$Button1.Width = 75
$Button1.OnClick = 'StartButton_Click($TestArray)'
   
$Button3 = $Form.Controls.Button
$Button3.Anchor = 5
$Button3.TextAlign = 32
$Button3.Enabled = "True"
$Button3.FlatStyle = 2
$Button3.FontBold = "False"
$Button3.FontItalic = "False"
$Button3.FontName = "Microsoft Sans Serif"
$Button3.FontSize = 8.25
$Button3.FontUnderline = "False"
$Button3.ForeColor = 0,0,0
$Button3.Height = 23
$Button3.Left = 285
$Button3.TabStop = "True"
$Button3.Tag = ""
$Button3.Text = "Quit"
$Button3.ToolTipText = ""
$Button3.Top = 210
$Button3.Visible = "True"
$Button3.Width = 75
$Button3.OnClick = 'ExitButton_Click()'

;*************************************
Global $Count, $rc, $File, $result, $serv, $Left, $Top, $ScreenWidth 
Global $Testarray[]
 
$rc=SetOption('novarsinstrings','on')
$ScreenWidth = $Form1.Screen.Width

$Form.Show

machlist()
On_Click()

$Form.OnResize = "OnResize()"
$Form.Running = 1
 
While $Form.Running
 $= Execute($Form.DoEvents)
Loop
 
Exit 1

;*************************************

Function OnDoubleClick()
 If NOT $Form.Visible OR $Form.WindowState = $System.FormWindowState.Minimized
  $Form.WindowState = $System.FormWindowState.Normal
  $Form.Show()
  $Form.Activate()
 EndIf
EndFunction

;*************************************

Function OnResize()
 If $Form.WindowState = $System.FormWindowState.Minimized
  $Form.Hide()
  $Form.NotifyIcon.Visible = True
 EndIf
EndFunction

;*************************************

Function OnExit()
 $Form.Running = 0
EndFunction

;*************************************

Function enr()

  $count=0 
  Del @SCRIPTDIR+"\serv.txt" 
  $=Open( 3 , @SCRIPTDIR+"\serv.txt" , 5 )
 
  For $xx=0 to ($ListBoxx2.listcount-1) 
    $ListBoxx2.ListIndex=$xx         
    $x = WriteLine( 3 , $ListBoxx2.text + @CRLF )
    $Count = $Count + 1     
  Next
 
  $=Close(3)   
  $ret=$form.MessageBox("List is update." + Chr(13) + Chr(10) + "" + Chr(13) + Chr(10) + $count+" records.","ServAlert",64)
 
EndFunction

;*************************************

Function machlist()

  $lst1="" 
  $=Open (1, @SCRIPTDIR+'\serv.txt', 2)
  $Serv = ReadLine (1)
   
  While @Error = 0   
    $lst1=$lst1+"~~"+$serv
    $ListBoxx2.additem($serv)
    $Serv = ReadLine (1) 
  Loop
 
  $=Close(1) 
  $lstar=Split($lst1,"~~")
   
  For Each $pc in netview2() 
    If isinarray($lstar,$pc)=0
      $ListBoxx1.additem($pc)     
    EndIf 
  Next
   
  $nbpc=$ListBoxx2.listcount
 
EndFunction

;*************************************

Function addpc()

  $ListBoxx2.additem($ListBoxx1.text)
  $ListBoxx1.removeitem($ListBoxx1.listindex) 
  $nbpc=$ListBoxx2.listcount   
  On_Click()
 
EndFunction

;*************************************

Function rempc()
 
  $ListBoxx2.removeitem($ListBoxx2.listindex) 
  $nbpc=$ListBoxx2.listcount
  On_Click()
 
EndFunction

;*************************************

Function On_Click()

  $cx=1
  For Each $Element in $TestArray         
    $rc=Execute('$label'+$cx+'.Hide')
    $rc=Execute('$labela'+$cx+'.Hide')
    $cx=$cx+1
  Next

  ReDim $TestArray[]
 
  $count=0

  For $x=0 to ($ListBoxx2.listcount-1)
 
    $ListBoxx2.ListIndex=$x
    $serv=$ListBoxx2.text
   
    ReDim Preserve $TestArray[$count]
   
    $TestArray[$Count] = $Serv
    $Count = $Count + 1 
   
  Next
                   
  $num=1
     
  For Each $Element in $TestArray           
    Build_Array($element, $num)       
    $num=$num+1                 
  Next

  $button1.enabled ='true'
  $Left = 5
  $Top = 250

  Display_Array()

EndFunction         

;*************************************
 
Function ExitButton_Click()
  $form.hide
  Quit()
EndFunction                 

;*************************************
 
Function StartButton_Click($TestArray)

  $pause=((($ListBoxx2.listcount-1)*1000)+60000)
  $button1.enabled='false'

  Test ($TestArray)

  $Timer = $Form.Controls.Timer
  $Timer.Interval = $pause
  $Timer.Ontimer = 'Test ($TestArray)'

EndFunction

;*************************************

Function Test($TestArray)

  $Form.Text = "ServAlert Checking"
  $Form.icon=$System.BuiltinIcons(53)
  $Form.NotifyIcon.Text = $Form.Text

  $listboxx1.enabled="false"
  $listboxx2.enabled="false"
  $Buttonx1.enabled="false"

  $err=0
  $num=1
  $cs=0
 
  $flashicon=$System.BuiltinIcons(34)
 
  For Each $Element in $TestArray

    $Form.icon=$System.BuiltinIcons(53) 
    $Form.NotifyIcon.Icon = $Form.Icon
   
    $cs=$cs+1
    If $cs>4 $cs=0 EndIf
 
    Select
      Case $cs=0
        $ch="."
      Case $cs=1
        $ch=".."
      Case $cs=2
        $ch="..."
      Case $cs=3
        $ch="...."
      Case $cs=4
        $ch="....."
      Case 1
        $ch=""
    EndSelect

    $Form.Text = "ServAlert Checking "+$ch
 
    $rc=Execute('$Label'+$num+'.BackColor = Yellow')
    $rc=Execute('$Label'+$num+'.ForeColor = black')

    Shell 'CMD.EXE /c PING '+$Element+' -n 3 | find /i "TTL" >nul'
 
    If @error = 0
      $rc=Execute('$Label'+$num+'.BackColor = LightGreen')     
    Else
      $rc=Execute('$Label'+$num+'.BackColor = Red')           
      $servs=$element   
      $err=1
      $flashicon=$System.BuiltinIcons(33)
      Run ("%COMSPEC% /e:1024 /c kix32 .\ermes.kix $serv="+$servs)
    EndIf

    $=Execute($Form.DoEvents(1))
 
    $num=$num+1
 
    $Form.icon=$flashicon
    $Form.NotifyIcon.Icon = $Form.Icon
    Sleep 0.1
 
  Next

  $listboxx1.enabled="true"
  $listboxx2.enabled="true"
  $Buttonx1.enabled="true"
  $Form.Text = "ServAlert waiting"
  $Form.NotifyIcon.Text = $Form.Text

  If $err=0
    $Form.icon=$System.BuiltinIcons(34)
    $Form.NotifyIcon.Icon = $Form.Icon
  Else
    $Form.icon=$System.BuiltinIcons(33)
    $Form.NotifyIcon.Icon = $Form.Icon
  EndIf

EndFunction

;*************************************

Function stop()
  $Form3.hide   
EndFunction

;*************************************

Function Build_Array($Element, $num)
 
  $rc=Execute('$Label'+$num+' = $Form.Controls.textbox')
  $rc=Execute('$Label'+$num+'.hide')
  $rc=Execute('$Label'+$num+'.Top = 50')
  $rc=Execute('$Label'+$num+'.Left = 50')
  $rc=Execute('$Label'+$num+'.BackColor = 0,0,0')
  $rc=Execute('$Label'+$num+'.ForeColor = 255,255,255')
  $rc=Execute('$Label'+$num+'.Alignment = 2')
  $rc=Execute('$Label'+$num+'.Width = 80')
  $rc=Execute('$Label'+$num+'.Height = 18')
  $rc=Execute('$Label'+$num+'.Text = $Element')               
 
EndFunction

;*************************************

Function Display_Array()
 
  $Form.Height = 320
  $num=1

  For Each $Element in $TestArray
     
      $rc=Execute('$Label'+$num+'.top = '+$Top)
      $rc=Execute('$Label'+$num+'.left = '+$Left)
      $rc=Execute('$Label'+$num+'.show')
     
      If $Left < 364
        $Left = $Left + 90
      Else
        $Left = 5
        $Top = $Top + 35
        $Form.Height = $Form.Height+40
      EndIf
       
    $num=$num+1
     
  Next

EndFunction

;FUNCTION      NetView2()
;
;AUTHOR        Jens Meyer (sealeopard@usa.net)
;
;CONTRIBUTOR   Shawn Tassie
;
;ACTION        Enumerate all announced computers in your domain
;
;VERSION       1.2 (fixed bug in SHELL string)
;              1.1
;
;DATE CREATED  2002/05/14
;
;DATE MODIFIED 2003/05/31
;
;KIXTART       4.12+
;
;SYNTAX        NetView2([Domain,Comment])
;
;PARAMETERS    DOMAIN
;              Specifies the domain to enumerate. If domain is omitted, returns a
;              list of all announced computers in the current domain.
;
;              COMMENT
;              Optional boolean to determine whether to return the associated computer
;              comment (separated by a comma from the computername)
;
;RETURNS       An array of strings representing all the computers in the domain
;
;REMARKS       This UDF returns a list of computers that are PINGable. Computers, that
;              are members of the domain but are currently not connected to the domain,
;              will not be listed. For a list of joined computers independent of whether
;              they are on- or off-line use COMNetView().
;
;              Slightly improved version of Shawn's NetView() UDF
;              at http://www.kixtart.org/cgi-bin/ultimatebb.cgi?ubb=print_topic;f=12;t=000059
;
;DEPENDENCIES  none
;
;EXAMPLE       for each $computer in netview2()
;                ? ''+$computer
;              next
;
;KIXTART BBS   http://www.kixtart.org/cgi-bin/ultimatebb.cgi?ubb=get_topic;f=12;t=000202
;
Function NetView2(optional $domain, optional $commentflag)
  Dim $array[255]
  Dim $ReDim, $i, $j, $tempfile
  Dim $filehandle, $retcode, $line
  Dim $name, $comment

  $ReDim = 255
  $i = 0
  $j = 0
  $tempfile = '%temp%\netview.tmp'

  If $domain
    $domain = '/domain:'+Trim($domain)
  EndIf

  If VarType($commentflag)
    $commentflag=Val($commentflag)
  Else
    $commentflag=0
  EndIf

  If Exist($tempfile)
    Del $tempfile
  EndIf

  Shell '%comspec% /c net view '+$domain+' >"'+$tempfile+'"'

  If @error = 0
    $filehandle=FreeFileHandle()
    $retcode=Open($filehandle,$tempfile)

    For $j = 1 to 5
      $line = ReadLine($filehandle) ; skip headings
    Next

    While @error = 0
      $name= Trim(SubStr($line,3,InStr($line,' ')-1))
      $comment = Trim(Right($line,Len($line)-InStr($line,' ')))
      If $commentflag
        $array[$i]=$name+','+$comment
      Else
        $array[$i]=$name
      EndIf
      $i=$i+1
      If $i = $ReDim
        $ReDim=$ReDim*2
        ReDim preserve $array[$ReDim]
      EndIf
      $line = ReadLine($filehandle)
    Loop
    $retcode=Close($filehandle)
    Del $tempfile
    If $i
      ReDim preserve $array[$i-4]
      $netview2 = $array
      Exit @error
    EndIf
  EndIf

  $netview2 = 0
  Exit @error
EndFunction

;*************************************     

;FUNCTION      IsInArray
;
;ACTION        Checks if a string is an element of an array of strings
;
;AUTHOR        Jens Meyer (sealeopard@usa.net)
;
;VERSION       1.4 (changed output to array only if element positions
;                   are to be returned, corrected example)
;              1.3
;
;DATE CREATED  2001/12/19
;
;DATE MODIFIED 2003/05/31
;
;KIXTART       4.20
;
;SYNTAX        ISINARRAY(ARRAY, STRING [, POS])
;
;PARAMETERS    ARRAY
;              Array of strings
;
;              STRING
;              Required string to search for in array
;
;              POS
;              Optional boolean indicating whether to return the
;              indices of all found strings as an array
;
;RETURNS       1 if string is found in any element of the array, otherwise 0
;              Alternatively an array of string indices
;
;REMARKS       Function handles an array with a maximum of 26 dimensions
;
;DEPENDENCIES  none
;
;EXAMPLE       $string='User1'
;              $array[0]='User0'
;              $array[1]='User1'
;              $rc=isinarray($array,$string)
;
;KIXTART BBS   http://www.kixtart.org/cgi-bin/ultimatebb.cgi?ubb=get_topic&f=12&t=000098
;
Function isinarray($array,$string, optional $pos)
  Dim $element, $cmd, $vars, $arraydim, $a, $rc, $posvars

  $isinarray=0
  $pos=Val($pos)

  Select
  Case VarType($array) & 8192
    Select
    Case Ubound($array,2)=-1
      If AScan($array,$string)=-1
        $isinarray=0
        Return
      Else
        If $pos
          $isinarray=''
          For $a=0 to Ubound($array)
            If $array[$a]=$string
              $isinarray=$isinarray+','+$a
            EndIf
          Next
          $isinarray=Split(SubStr($isinarray,2),',')
          If Ubound($isinarray)=0
            $isinarray=$isinarray[0]
          EndIf
        Else
          $isinarray=1
        EndIf
        Return
      EndIf
    Case Ubound($array,27)=-1
      $arraydim=0
      Do
        $arraydim=$arraydim+1
      Until Ubound($array,$arraydim)=-1
      $arraydim=$arraydim-1
      $vars='$sub_a'
      For $a=2 to $arraydim
        $vars=$vars+', $sub_'+Chr($a+96)
      Next
      $cmd='dim '+$vars+@CRLF
      $cmd=$cmd+'$isinarray=""'+@CRLF
      For $a=1 to $arraydim
        $cmd=$cmd+'for $sub_'+Chr($a+96)+'=0 to ubound($array,'+$a+')'+@CRLF
        $posvars=$posvars+'+","+$sub_'+Chr($a+96)
      Next
      $posvars=SubStr($posvars,6)
      $cmd=$cmd+'if $array['+$vars+']=$string'+@CRLF
      $cmd=$cmd+'if $pos'+@CRLF
      $cmd=$cmd+'$isinarray=$isinarray+chr(13)+'+$posvars+@CRLF
      $cmd=$cmd+'else'+@CRLF
      $cmd=$cmd+'$isinarray=1'+@CRLF
      $cmd=$cmd+'return'+@CRLF
      $cmd=$cmd+'endif'+@CRLF
      $cmd=$cmd+'endif'+@CRLF
      For $a=1 to $arraydim
        $cmd=$cmd+'next'+@CRLF
      Next
      $cmd=$cmd+'$isinarray=split(substr($isinarray,1),chr(13))'+@CRLF
      $cmd=$cmd+'if ubound($isinarray)=0'+@CRLF
      $cmd=$cmd+'$isinarray=$isinarray[0]'+@CRLF
      $cmd=$cmd+'endif'+@CRLF
      $rc=Execute($cmd)
    Case 1
      $isinarray=0
    EndSelect
  Case $string=''
    $isinarray=0
  Case $string=$array
    $isinarray=1
  Case 1
    $isinarray=0
  EndSelect
EndFunction

ermes.kix
Code:

Break on

$Form3 = CreateObject("Kixtart.Form")
$Form3.Height = 280
$Form3.Text = "ServAlert"
$Form3.Width = 296
$Form3.icon=$System.BuiltinIcons(33)

$TextBox21 = $Form3.TextBox()
$TextBox21.FontBold = "True"
$TextBox21.backcolor = "red"
$TextBox21.FontSize = 20
$TextBox21.Height = 159
$TextBox21.Left = 15
$TextBox21.Multiline = "True"
$TextBox21.TextAlign = 2
$TextBox21.Top = 15
$TextBox21.Width = 254
$TextBox21.ScrollBars = 2
$TextBox21.forecolor="yellow"
$TextBox21.Text = "WARNING"+@CRLF+$serv+@CRLF+@CRLF+"no reply !"

$Button21 = $Form3.Button()
$Button21.Height = 23
$Button21.Left = 105
$Button21.Text = "OK"
$Button21.Top = 195
$Button21.Width = 75
$Button21.onclick="quit"

$Form3.Center
$Form3.Show
While $Form3.Visible
 $=Execute($Form3.DoEvents)
Loop

Exit 1

_________________
There is no stupid question. Whoever seeks is never stupid because he will know ...
Bruno.
Back to top
View user's profile Send private message
Sealeopard
KiXforms Aficionado
KiXforms Aficionado


Joined: 05 Mar 2003
Posts: 436
Location: Boston, MA

PostPosted: Fri Nov 26, 2004 1:20 pm    Post subject: Reply with quote

You should use ASCAN() instead of IsInArray() for one-dimensional arrays.
_________________
Jens

'There are two kinds of vessels, submarines and targets.'
Back to top
View user's profile Send private message Send e-mail MSN Messenger
bruno
KiXforms Regular
KiXforms Regular


Joined: 19 May 2003
Posts: 44
Location: France (Europe)

PostPosted: Fri Nov 26, 2004 1:50 pm    Post subject: Reply with quote

your right. I use isinarray in over scripts and I just copy and paste and forget ascan. Embarassed

I've make some modifications. The icon display in the status bar are replaced by skull images (reg,green,yellow). The french messages in my source are translate in english for the forum.

Thank you.

_________________
There is no stupid question. Whoever seeks is never stupid because he will know ...
Bruno.
Back to top
View user's profile Send private message
Gargoyle
KiXforms Aficionado
KiXforms Aficionado


Joined: 30 Dec 2003
Posts: 366
Location: Arizona

PostPosted: Fri Jan 28, 2005 7:03 pm    Post subject: Reply with quote

Well I am back after having moved from Alaska to Arizona, and I like the new version.

But I am not getting any listing in the available box. Are there parameters that I need to specify?

Edited to add:

Nevermind, my new employer has network browsing turned off. Embarassed

I will have to go back to my old script that uses the INI file.

_________________
Parents were invented to make children happy by giving them something to ignore.
Back to top
View user's profile Send private message
bruno
KiXforms Regular
KiXforms Regular


Joined: 19 May 2003
Posts: 44
Location: France (Europe)

PostPosted: Mon Jan 31, 2005 8:30 am    Post subject: Reply with quote

Gargoyle,

Maybe you have to specify the domain name to netview2 (optional but...).
See in the function machlist()

Or you can change this function to read a file.
Or add manualy the server in the file "serv.txt" in the folder of the script.

Please let me know...

_________________
There is no stupid question. Whoever seeks is never stupid because he will know ...
Bruno.
Back to top
View user's profile Send private message
Gargoyle
KiXforms Aficionado
KiXforms Aficionado


Joined: 30 Dec 2003
Posts: 366
Location: Arizona

PostPosted: Mon Jan 31, 2005 9:08 pm    Post subject: Reply with quote

Stating the Domain in the machlist() function did not help. But that is to be expected with browsing turned off (I checked with the desktop group and that is what they did).

What I did end up doing was to prepopulate the serv.txt file and it worked fine from there.

Now I am onto a much tougher and bigger project writing a SHA-1 algorithym to work within Kix, wish me luck on that one.

_________________
Parents were invented to make children happy by giving them something to ignore.
Back to top
View user's profile Send private message
Display posts from previous:   
Post new topic   Reply to topic    KiXforms Forum Index -> Script Archive All times are GMT
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum


Powered by phpBB © 2001, 2005 phpBB Group