break on


; kixtart version 4
; kixforms build 10
 
$BLUE = &B00000
$TITLE = "KiXtart Messenger"
 
$form = createobject("kixtart.form")
$form.caption = $TITLE
$form.icon = ""
$form.height = 481
$form.width = 318
$form.fontsize = 12
 
; Create our menu 
 
;$file = $form.menu("File")
;$format = $form.menu("Format")
;$font = $format.menu("Font")
;$smlfont = $font.menubutton("Small","$$message.fontsize = 10")
;$medfont = $font.menubutton("Medium","$$message.fontsize = 12")
;$bigfont = $font.menubutton("Large","$$message.fontsize = 18")
;$exit = $file.menubutton("Exit","quit()")
;$about = $form.menu("About")
;$aboutscript = $about.menubutton("About $TITLE","about_click")
 
; Draw the form
 
$form.backcolor = $form.rgb(255,255,255)
$form.forecolor = &B00000
$form.drawwidth = 4
$form.rectangle(0,0,$form.scalewidth,380)
$form.fontname = "arial"
$form.fontsize = 16
$form.fontitalic = 1
$form.fontbold = 1
$form.printxy(60,380,"KiXtart")
$form.forecolor = &0555555
$form.fontitalic = 0
$form.printxy(137,380,"messenger")
$form.fontsize = 12
$form.forecolor = 0
$form.forecolor = &0AAAAAA
$form.fontsize = 10
$form.fontitalic = 1
$form.printxy(170,404,"powered by")
$form.fontsize = 18
$form.fontitalic = 0
$form.printxy(250,394,".kix")
$form.drawwidth = 3
$form.forecolor = &033CCFF
$form.line(30,420,300,420)
$form.forecolor = &0FF
$form.line(240,420,300,420)
$form.forecolor = &0FF0000
$form.line(260,420,300,420)
$form.forecolor = &0FF00
$form.line(280,420,300,420)
 
; Create our controls
  
$form.fontsize = 10
$form.forecolor = $BLUE
$form.printxy(15,33,"Computer Name:")
$computer = $form.textbox("",15,50,275,25)
$computer.forecolor = $BLUE
$form.printxy(15,100,"Message:")
$form.fontsize = 12
$message = $form.textbox("",15,118,275,200)
$message.multiline = 1
$message.forecolor = $BLUE
$send = $form.commandbutton("Send",240,325,50,45)
$send.onclick = "send_click"
$send.default = 1
$send.fontsize = 10
 
; Run the form
 
$form.center
$form.show
$computer.setfocus
while $form.visible
 $=execute($form.doevents)
loop
 
exit
 
function send_click
 dim $msg,$name
 $name = $computer.text
 if not $name
  $= $form.msgbox("Please enter a valid computer name","Computer Name")
  $computer.setfocus
  return
 endif
 $msg = $message.text
 shell '%comspec% /c net send $name "$msg" >nul 2>nul'
endfunction
 
function about_click
 dim $about,$ok
 $about = createobject("kixtart.form")
 $about.borderstyle = 1
 $about.width = 300
 $about.height = 200
 $about.caption = "About $TITLE"
 $about.fontname = "verdana"
 $about.fontsize = 16
 $about.fontbold = 1
 $about.printxy(30,20,"$TITLE")
 $about.fontsize = 10
 $about.fontbold = 0
 $about.printxy(100,60,"Version 1.0")
 $about.printxy(115,90,"Shawn")
 $ok = $about.commandbutton("OK",110,120)
 $ok.default = 1
 $ok.onclick = "$$about.hide"
 $about.center
 $about.show
 while $about.visible
  $=execute($about.doevents)
 loop
endfunction